සියලුම පවර්පොයින්ට් විනිවිදකවල භාෂාව එකවර වෙනස් කරන්නේ කෙසේද?

මගේ සියලුම විනිවිදකවල සනාථ කිරීමේ භාෂාව පවර්පොයින්ට් එකක වෙනස් කිරීමට මට අවශ්‍යය. භාෂා මනාප මෙනුව හරහා භාෂාව සැකසීමට මම උත්සාහ කළෙමි, කෙසේ වෙතත් මෙය වෙනස් කරන්නේ නව බල ස්ථාන සඳහා පමණි.

සමස්ත පවර්පොයින්ට්හි භාෂාව පහසුවෙන් වෙනස් කිරීමට, දර්ශන පටිත්ත විවෘත කර ලුහු line ු සටහන් තෝරන්න .

දැන් ඔබන්න

• Ctrl+ Aසියල්ල තෝරා ගැනීමට.
• මෙවලම් → භාෂාව set සැකසීමට ඔබේ භාෂාව තෝරන්න.

ඒ හා සමානව ඔබ සෑම දෙයක්ම තෝරාගෙන ඇති අතර ඔබට අකුරු, වර්ණ වැනි වෙනත් දේ වෙනස් කළ හැකිය. ඇත්ත වශයෙන්ම බොහෝ විට මෙය විනිවිදක මාස්ටර් වෙනස් කිරීමෙන් වඩා හොඳ වුවද, බොහෝ සංස්කාරකවරුන් සිටින ඉදිරිපත් කිරීමකට 'දෘ' 'හැඩතල ගැන්වීමේ කට්ටලයක් තිබිය හැකිය. යටින් පවතින ස්වාමියාගෙන් බැහැර වන අතර ස්ථාවර වීමට නැවත සැකසීම අවශ්‍ය වේ. ඔබට තනි විනිවිදක ප්‍රධාන ශෛලියට නැවත සැකසිය හැක, නමුත් මෙය ස්ථාන දරන්නන් ද චලනය වීමට හේතු විය හැක, සමහර අවස්ථාවල එය නුසුදුසු විය හැකිය.

පවර්පොයින්ට් 2013

• දැක්ම → දළ සටහනක් → හරහා සියලු විනිවිදක (අ වම් මෙනුව තුළ) තෝරා Ctrl+ A.
• සමාලෝචන → භාෂා → Set සෝදුපත් භාෂා ... → කට්ටලයක් ඔබගේ භාෂාව තෝරාගන්න.

මා සම්බන්ධයෙන් - පවර්පොයින්ට් නැවත ආරම්භ කිරීම අවශ්‍ය විය. බොහෝ විට මම සංස්කරණ භාෂාවද වෙනස් කර ඇති නිසා විය හැකිය :

• සමාලෝචන → භාෂා → Set සෝදුපත් භාෂා ... → භාෂා අභිරුචි → සංස්කරණය භාෂා තෝරන්න .

පවර්පොයින්ට් 2010 භාවිතා කරමින් මම ලුහු line ු සටහන් මෙනුව විවෘත කළෙමි -

සියලුම පෙළ (Ctrl + A) තෝරා, භාෂා මෙනුව විවෘත කර මගේ සනාථ කිරීමේ භාෂාව සකසා ඇත

එය ක්‍රියාත්මක විය!

භාෂා මෙනුව සමාලෝචන රිබන් පටිත්තෙහි පිහිටා ඇත (විනිවිදක දර්ශන පටිත්තෙන් පසුව සහ තිර පිටුවේ නොපෙනේ).

පවත්නා පිළිතුරු දළ සටහනෙහි ඇති පෙළ සඳහා ක්‍රියා කරයි. අවාසනාවට මගේ නඩුවේ මෙය සංඛ්‍යා, වගු යනාදිය ඇතුළුව පෙළෙහි සැලකිය යුතු කොටසක් ආවරණය නොකරයි.

මෙම සාර්ව මට ගැටලුව විසඳීය:

 Sub ChangeProofingLanguageToEnglish()
    Dim j, k, m, scount, fcount, gcount As Integer
    scount = ActivePresentation.Slides.Count
    For j = 1 To scount
        fcount = ActivePresentation.Slides(j).Shapes.Count
        For k = 1 To fcount
            If ActivePresentation.Slides(j).Shapes(k).HasTextFrame Then
                ActivePresentation.Slides(j).Shapes(k) _
                .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
            If ActivePresentation.Slides(j).Shapes(k).Type = msoGroup Then
                gcount = ActivePresentation.Slides(j).Shapes(k).GroupItems.Count
                For m = 1 To gcount
                    If ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m).HasTextFrame Then
                    ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m) _
                    .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
                Next m
            End If
        Next k
    Next j
End Sub

ඉහත සාර්වයේ භාවිතා වන "msoLanguageIDEnglishUS" ඕනෑම අපේක්ෂිත භාෂාවක් මගින් ප්‍රතිස්ථාපනය කළ හැකිය. භාෂා පිළිබඳ සම්පූර්ණ ලැයිස්තුව මෙම ලිපියෙන් සොයාගත හැකිය

( මෙහි මුල් මැක්‍රෝව පළ කළ ගනේෂ් කුමාර්ට ණය හිමිවේ . මම පළමු මට්ටමේ හැඩ ගැන්වීම් සඳහා සහය එක් කළෙමි. එය තවදුරටත් වැඩිදියුණු කිරීම සඳහා සාර්ව වෙනත් කණ්ඩායම් අඩංගු කණ්ඩායම් සෙවීම සඳහා පුනරාවර්තනයක් කළ හැකිය.)

සියලු අයිතම අපේක්ෂිත භාෂාවට වෙනස් කරන පුනරාවර්තන අනුවාදයක් ලබා දීමට මම ඉනිගෝගේ පිළිතුර මත දියුණු විය .

මෙම අනුවාදය කණ්ඩායම් වර්ගයක් වන එක් එක් හැඩය පුනරාවර්තනය කරයි. සමහර අත්හදා බැලීම කරන බව හඟවන msoGroupහා msoSmartArtඔබ පෙළ වස්තූන් පැවැත්වීමට හැකි බව හැඩ වෙනත් වර්ග සොයා නම් ලැයිස්තුවට එක් කරන්න නිදහස් හැඟීම - කණ්ඩායම වෙනස් වේ.

Sub ChangeProofingLanguageToEnglish()
    Dim j As Long, k As Long
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDEnglishUK

    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), _
              languageID
        Next k
    Next j
End Sub


Sub ChangeAllSubShapes(targetShape As shape, languageID As MsoLanguageID)
    Dim i As Long

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

ඉනිගෝ, ඩන්කන්, මරියා සහ ඩොම් දේව්ගේ පිළිතුරු මත පදනම්ව, මෙය හැඩතල, වගු, කණ්ඩායම්, ස්මාර්ට්ආර්ට්, දැන් සහ අනාගතයේදී ක්‍රියා කරයි:

Sub ChangeProofingLanguageToFrench()
    Dim j, k As Integer
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDFrench

    'Loop all the slides in the document, and change the language
    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), languageID
        Next k
    Next j

    'Loop all the master slides, and change the language
    For j = 1 To ActivePresentation.SlideMaster.CustomLayouts.Count
        For k = 1 To ActivePresentation.SlideMaster.CustomLayouts(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.SlideMaster.CustomLayouts(j).Shapes(k), languageID
        Next k
    Next j

    'Change the default presentation language, so that all new slides respect the new language
    ActivePresentation.DefaultLanguageID = languageID
End Sub

Sub ChangeAllSubShapes(targetShape As Shape, languageID As MsoLanguageID)
    Dim i As Integer, r As Integer, c As Integer

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    If targetShape.HasTable Then
        For r = 1 To targetShape.Table.Rows.Count
            For c = 1 To targetShape.Table.Columns.Count
                targetShape.Table.Cell(r, c).Shape.TextFrame.TextRange.languageID = languageID
            Next
        Next
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

ඩන්කන්ගේ අනුවාදය වගු හැර අන් සියල්ලටම හොඳින් ක්‍රියා කරයි. වගු සමඟ වැඩ කරන බව පෙනෙන තවත් කේතයක් මට හමු විය: /programming/4735765/powerpoint-2007-set-language-on-tables-charts-etc-that-contains-text

Public Sub changeLanguage()
    On Error Resume Next
    Dim gi As GroupShapes '<-this was added. used below
    'lang = "English"
    lang = "Norwegian"
    'Determine language selected
    If lang = "English" Then
        lang = msoLanguageIDEnglishUK
    ElseIf lang = "Norwegian" Then
        lang = msoLanguageIDNorwegianBokmol
    End If
    'Set default language in application
    ActivePresentation.DefaultLanguageID = lang

    'Set language in each textbox in each slide
    For Each oSlide In ActivePresentation.Slides
        Dim oShape As Shape
        For Each oShape In oSlide.Shapes
            'Check first if it is a table
            If oShape.HasTable Then
                For r = 1 To oShape.Table.Rows.Count
                    For c = 1 To oShape.Table.Columns.Count
                    oShape.Table.Cell(r, c).Shape.TextFrame.TextRange.LanguageID = lang
                    Next
                Next
            Else
                Set gi = oShape.GroupItems
                'Check if it is a group of shapes
                If Not gi Is Nothing Then
                    If oShape.GroupItems.Count > 0 Then
                        For i = 0 To oShape.GroupItems.Count - 1
                            oShape.GroupItems(i).TextFrame.TextRange.LanguageID = lang
                        Next
                    End If
                'it's none of the above, it's just a simple shape, change the language ID
                Else
                    oShape.TextFrame.TextRange.LanguageID = lang
                End If
            End If
        Next
    Next End Sub

මාස්ටර්ගලන් සපයන පිළිතුරට අමතරව සහ අලුතින් ටයිප් කරන ලද පෙළ සම්බන්ධයෙන් අදහස් දැක්වීමටද:

ඔබ දුටුවහොත්, ඔබ නව පෙළ ටයිප් කිරීමට පටන් ගන්නා සෑම විටම එම භාෂාව ස්වයංක්‍රීයව වෙනස් වනු ඇත (එය ඉතා කරදරකාරී ය), ඔබ පවර්පොයින්ට් සඳහා වත්මන් පෙරනිමි භාෂාව වෙනස් කළ යුතුය:

• පවර්පොයින්ට් කවුළුව සක්‍රිය කවුළුවක් බවට වග බලා ගන්න
• තුළ Windows Taskbar(ඔව්, ඇත්තටම පවර් පොයින්ට් කර නැති), චෙක් නම් Language barදෘශ්යමාන වේ,
  • වෙත නොගියහොත් Control Panel > Region and Language > Keyboards and Languages. ක්ලික් කරන්න Change keybords..., Language barටැබ් වෙත මාරු වී Docked in the taskbarවිකල්පය පරීක්ෂා කරන්න . (මෙය Win7 වෙතින් වන අතර අනෙක් අනුවාදවල එය ටිකක් වෙනස් විය හැකිය).
• දැන් යතුරු ක්‍රියාව - Language barකාර්ය තීරුවේ, භාෂා කේතය ක්ලික් කර EN වෙත මාරු වන්න (ඔබට දැනට පවර්පොයින්ට් හි ඉංග්‍රීසි භාවිතා කිරීමට අවශ්‍ය නම්). මෙතැන් සිට, පවර්පොයින්ට් හි සියලුම නව පෙළ තෝරාගත් භාෂාවෙන් වනු ඇත :-)
• ඔබට ඔබේ මුල් භාෂාවෙන් ලිවීමට අවශ්‍ය නම් එය නැවත වෙනස් කරන්න.

පවර්පොයින්ට් 2016 හි තවමත් හොඳින් ක්‍රියාත්මක වන මම 2014 දී නැවත එකතු කිරීමක් කළෙමි. Https://github.com/wobba/officeaddin/releases/tag/v1.0.1

එය භාවිතා කළ භාෂාවන් පරිලෝකනය කරන අතර එකවර වෙනස් කිරීමට ඔබට ඉඩ සලසයි.